excel生成动态的规律序列（Row/Column与Indirect函数）

Excel函数 2023-01-08

因为Row和Column的特殊性，我们可以利用此来生成有规律的序列，比如：
=Row(a1)下拉
=Column(a1)右拉

但这样的公式不利于再在外面套公式，所以我们利用数组的特性，将参数里的一个地址扩展成一个矩阵，比如：
=Row(a1:a6)
=Column(a1:f1)
这样一来，这两个公式都变成内存数组了，所以录入时要选取一个矩阵，Row公式是六行一列、Column公式是一行六列，录入公式后同时按下那个著名的组合键：Ctrl+shift+enter，我们看到的结果就是一个内存数组的结果，这种公式可以在外面再套公式进行运算。

不过这种写法我的公式里不常见，因为我总是遵循那个“变态的省字数和原则”，不顾资源将公式写成:
=Row(1:6)
=Column(a:f)

但是以上这些都是静态的，如果希望Row的结果随某个单元格的变化而变化，直接写成Row(a1*2)是绝对不行的，因为Row和Column的参数只认引用，这里就需要用间接引用函数来帮助Row和Column实现动态结果。
引用函数有Indirect、Offset和Index的一部分，不过现实中，Row/Column套Indirect的更多见一些：
=Row(Indirect("a"&b2*2))
=Column(Indirect("r10c"&b10*2,))

将间接引用函数用到数组上，本来引用1至6行的，直接写成：
=1:6
改用间接引用以后就变成了：
Indirect("1:6")
再与Row/Column合作，公式就写成：
=Row(Indirect("1:6"))
=Column(Indirect("a:f"))
这两个公式其实和刚才讲到的第二组和第三组公式没有区别，只不过前两个是直接引用，这里用了间接引用。
（注意：因为Row和Column可以引用自身，所以Row/Column套任何函数以后，仍然可以引用自身，但Indirect却不行，所以如果是直接写“Indirect("1:6")”，这公式不能写在1至6行里的任意单元格里，否则报循环。）

有了间接引用，变化也就多端了，比如我们要生成的不一定是6个数，而是和某单元格里的字数相动态，那公式就写成：
=Row(Indirect("1:"&Len(s13)))
=Column(Indirect("c1:c"&len(s13),))

另外补充一个，Indirect的两种引用和其变种：
=Indirect("单元格引用",参数)

行号列标引用：
=Indirect("a1")
=Indirect("A"&公式)

R1C1引用：
=Indirect("r1c1",)
=Indirect("r"&公式&"c"&公式,)
=Indirect(text(11,"r0c0"),)
=Indirect("r[1]c[1]",)
=Indirect("r1c",)
=Indirect("rc1",)

上一篇：Indirect函数里的参数要不要加引号？下一篇：Excel中可以引用自身的函数

excel生成动态的规律序列（Row/Column与Indirect函数）

热门文章

最新文章

标签列表