vlookup函数的是一种使用方法你一定要学会啊！

Excel函数 2023-01-08

vlookup这个函数在数据查找中可以说是一个名副其实的万能函数，可能对于大家或多或少都有了解过这个函数。今天我们就来全面学习一下这个万能函数的全部11种用法，让你熟练的掌握这个函数的所有操作。

函数公式简介：=vlookup(你要找的值，你要查找的区域，查找区域中往右第几位，0)。

在这里第四个参数0位精确查找，1为模糊查找，工作中常用的就是0。下面我们来学习一下这个函数的操作用法。

用法1：数据简单查找

案例：简单查询张三5月销量

函数=VLOOKUP(B10,$A$1:$H$6,7,0)

解析：第一参数为要查询的姓名张三，第二参数为数据源，第三参数为五月份张三的数据在从姓名起往右的第7列，第四参数为0也就是精确查找这个值。

用法2：Vlookup搭配Column函数自动变列计算

案例：搭配column函数自动变化第三参数批量查询杨三和王吧4-6月数据。

函数=VLOOKUP($B10,$A$1:$H$6,COLUMN(C10)+3,0)

解析：第一参数还是需要查询的人张三，注意B10单元格需要把列固定；第二参数函数对应区域不变；第三参数运用column返回当前列的方式自动变化，因为当前单元格为C10返回值为3，而4月数据为从左往右第6列，所以需要再加3。

用法3：vlookup搭配match函数进行精确查找

案例：搭配match函数自动变化第三参数批量查询杨三和王吧4-6月数据。操作技巧跟column函数类似。

函数=VLOOKUP($B10,$A$1:$H$6,MATCH(C$9,$A$1:$H$1,0),0)

解析：同colunm函数类似，主要变更第三参数。第三参数MATCH(C$9,$A$1:$H$1,0)=6，代表求出4月、5月、6月月份在标题行中所在的位置。

用法4：vlookup经典的向左查询

案例：根据工号在数据源中向左查找对应的姓名

函数={=VLOOKUP(C10,IF({1,0},$C$2:$C$6,$B$2:$B$6),2,0)}

解析：向左查询需要用到IF函数来进行二次判断。参数IF({1,0},$C$2:$C$6,$B$2:$B$6)，1代表条件成立C列能查到工号时，查询的区域从$C$2:$C$6到$B$2:$B$6，0代表条件不成立也就是C列查找不到工号时候，查询的区域从$B$2:$B$6到$C$2:$C$6。

用法5：vlookup查询出现错误值时为空处理

案例：数据源中没有这个人数据时，出现错误值时用空白单元格替换掉

函数=IFERROR(VLOOKUP(C9,$B$1:$G$6,6,0),"")

解析：IFEEROR函数为错误值处理函数，当出现错误值时可以用其他内容代替。函数参数为IFERROR（有错误值，执行下一步）。没有错误值时正常显示。

用法6：vlookup函数最快速度制作工资条

案例：运用vlookup函数从数据源中最快的制作工资条

函数=VLOOKUP($G96,$A$96:$E$104,COLUMN(B1),)

解析：根据数据源做工资条，主要的技巧有2个：1、我们往下拖动数据的时候，需要选中一行空白的单元格行，然后再往下移动即可；2、工资条前方提前输入数字1，这样往下拖动可以自动更换，然后在数据源中做辅助列1、2、3....，通过数字进行匹配查找。

用法7：vlookup函数计算个人所得税

案例：通过计算好的工资金额直接计算对应的个人所得税税率

函数=(G28-3500)*VLOOKUP(G28-3500,C28:E34,2)-VLOOKUP(G28-3500,C28:E34,3)

解析：这里的重点在于，需要先通过前面的金额区间对应的做好辅助列。以上税率为2018.10.1日变更前税率。

用法8：vlookup函数进行通配符（任意值）查找

案例：查找名称中带有镇流器产品的数量

函数=VLOOKUP("*"&F41&"*",$B$41:$D$47,3,0)

解析：*代表任意字符，运用&符号进行连接代表镇流器三个字前可以是任意内容。

用法9：如何用vlookup函数实现多条件查询

案例：求出日期和单号两个条件下的仓库入库数量

函数：{=VLOOKUP(G2&H2,IF({1,0},A:A&B:B,C:C),2,0)}

解析：关键点在于查找的条件值需要用&符号将两个条件连接成一个条件，同时第二参数运用IF判断函数同样的用&符号将查询区域进行连接。最后用CTRL+SHIFT+ENTER三键数值的方式进行计算。

用法10：vookup函数进行多数据求和

案例：求出对人员1-6月总销售金额

函数=SUM(VLOOKUP(B11,$A$2:$G$8,{2,3,4,5,6,7},0))

解析：vlookup函数求和重点有2个。1、第三参数查找的数据区域我们需要将每个月对应的列用{}数值的方式进行全部查找；2、当查找出来数据之后，最后用sum函数进行求和，最后用CTRL+SHIFT+ENTER三键数值的方式进行计算。

用法11：vlookup函数如何进行一对多查询

案例：通过姓名查找出当天的所有门禁刷卡数据

函数=IFERROR(VLOOKUP(ROW(A1),A:D,4,0),"")

解析：重点在于需要在数据源中做一列辅助列，函数为COUNTIF(B$2:B2,G$2)，作为辅助列后通过vlookup函数查找对应的行数进行数据查找，往下拖动的时候就可以匹配出所有的数据。IFERROR函数的用途在于当所有数据已经查找完，往下拖动出现错误值时用空格代替。

上一篇：excel怎么让输入的员工身份证号不重复且不超过18位下一篇：excel 如何最快核对两列数据的不同

vlookup函数的是一种使用方法你一定要学会啊！

热门文章

最新文章

标签列表